Oinarrizko hiztegia. Latina-Euskara

From MLV

Gidor Bilbaoren "Oinarrizko Hiztegia. Latina-Euskara" (Latina Euskara Hiztegia > LEH) prozesatzeko esperimentuetako emaitza batzuk ikusteko datu-base galdeketa sorta ematen du orrialde honek. Hiztegia bera Q1284 entitateak deskribatzen du.

Hiztegiaren edukien egituraketa

Egindako esperimentuen berri ematen duen artikulua prestatzen dihardugu.

Latinezko lemategia LiLa proiektuko lemategiarekin lerrokatzea

Egindako esperimentuen berri ematen duen artikulua prestatzen dihardugu.

Hiztegia Wikibase honetan

Egindako esperimentuen berri ematen duen artikulua prestatzen dihardugu.

Datu-base galdeketak

Sarrera guztiak

Galdeketa honek sarrera guztiak zerrendatzen ditu, LiLa eta Wikidatarekin dituzten loturekin. LiLa edo Wikidatarekiko lotura bat baino gehiago izanez gero, sarrera errepikatuta agertzen da, 

PREFIX ontolex: <http://www.w3.org/ns/lemon/ontolex#>
PREFIX mwb: <https://monumenta.wikibase.cloud/entity/>
PREFIX mdp: <https://monumenta.wikibase.cloud/prop/direct/>
PREFIX mp: <https://monumenta.wikibase.cloud/prop/>
PREFIX mps: <https://monumenta.wikibase.cloud/prop/statement/>
PREFIX mpq: <https://monumenta.wikibase.cloud/prop/qualifier/>
PREFIX mpr: <https://monumenta.wikibase.cloud/prop/reference/>
PREFIX mno: <https://monumenta.wikibase.cloud/prop/novalue/>
PREFIX lila: <http://lila-erc.eu/ontologies/lila/>


SELECT distinct ?source_id ?sarrera_burua ?wikibase_lexeme ?wikibase_lemma ?wikidata ?lila_uri
     
   WHERE {
?wikibase_lexeme mp:P6 [mps:P6 mwb:Q1284; mpq:P186 ?source_id; mpq:P187 ?sarrera_burua]; wikibase:lemma ?wikibase_lemma.
optional {?wikibase_lexeme mdp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
optional {?wikibase_lexeme mp:P185 ?lila_id_st. ?lila_id_st mps:P185 ?lila_id. bind(iri(concat("https://lila-erc.eu/lodview/data/id/",?lila_id)) as ?lila_uri)}
   
} 
order by xsd:integer(?source_id)

Try it!


LiLarekin oraindik modu ambiguoan lotutako sarrerak

#title:LEH sarrerak, oraindik LiLa lotura ambiguoa dutenak
PREFIX mwb: <https://monumenta.wikibase.cloud/entity/>
PREFIX mdp: <https://monumenta.wikibase.cloud/prop/direct/>
PREFIX mp: <https://monumenta.wikibase.cloud/prop/>
PREFIX mps: <https://monumenta.wikibase.cloud/prop/statement/>
PREFIX mpq: <https://monumenta.wikibase.cloud/prop/qualifier/>
PREFIX wikibase: <http://wikiba.se/ontology#>
SELECT ?source_id ?sarrera_burua ?sarrera_testua ?wikibase_lexeme ?wikibase_lemma ?lila_ids WHERE {
  ?wikibase_lexeme mp:P6 _:b31;
    wikibase:lemma ?wikibase_lemma.
  _:b31 mps:P6 mwb:Q1284;
    mpq:P186 ?source_id;
    mpq:P187 ?sarrera_burua;
    mpq:P198 ?sarrera_testua.
  {
    SELECT ?wikibase_lexeme (COUNT(?lila_id) AS ?lila_ids) WHERE { ?wikibase_lexeme mdp:P185 ?lila_id. }
    GROUP BY ?wikibase_lexeme ?lila_ids
  }
  FILTER(?lila_ids > 1 )
}
ORDER BY DESC (?lila_ids)

Try it!


LiLarekin modu unibokoan lotutako sarrerak

#title:LEH sarrerak, LiLarekin lotura unibokua dutenak
PREFIX mwb: <https://monumenta.wikibase.cloud/entity/>
PREFIX mdp: <https://monumenta.wikibase.cloud/prop/direct/>
PREFIX mp: <https://monumenta.wikibase.cloud/prop/>
PREFIX mps: <https://monumenta.wikibase.cloud/prop/statement/>
PREFIX mpq: <https://monumenta.wikibase.cloud/prop/qualifier/>
PREFIX wikibase: <http://wikiba.se/ontology#>
SELECT ?source_id ?wikibase_lexeme ?sarrera_burua ?sarrera_testua ?lila_link ?lila_lemma ?posLabel ?generoLabel ?infl_classLabel WHERE {
  ?wikibase_lexeme mp:P185 ?lila_st. filter not exists {?lila_st wikibase:rank wikibase:DeprecatedRank.}
  ?wikibase_lexeme wikibase:lemma ?wikibase_lemma.
  ?wikibase_lexeme mp:P6 [mps:P6 mwb:Q1284;
    mpq:P186 ?source_id;
    mpq:P187 ?sarrera_burua;
    mpq:P198 ?sarrera_testua].
  {
    SELECT ?wikibase_lexeme (COUNT(distinct ?lila_1id) AS ?lila_ids) WHERE { ?wikibase_lexeme mp:P185 ?l_st. ?l_st mps:P185 ?lila_1id. filter not exists {?l_st wikibase:rank wikibase:DeprecatedRank.} }
    GROUP BY ?wikibase_lexeme ?lila_ids
  }
  FILTER(?lila_ids = 1 )
  ?lila_st mpq:P187 ?lila_lemma; mps:P185 ?lila_id.
  bind(iri(concat("http://lila-erc.eu/data/id/",?lila_id)) as ?lila_link)
  optional {?lila_st mpq:P153 ?pos.}
  optional {?lila_st mpq:P194 ?genero.}
  optional {?lila_st mpq:P195 ?infl_class.}
 SERVICE wikibase:label { bd:serviceParam wikibase:language "eu,en". }          
}

Try it!


LiLarekin loturarik oraindik ez duten sarrerak

PREFIX mwb: <https://monumenta.wikibase.cloud/entity/>
PREFIX mp: <https://monumenta.wikibase.cloud/prop/>
PREFIX mps: <https://monumenta.wikibase.cloud/prop/statement/>
PREFIX mpq: <https://monumenta.wikibase.cloud/prop/qualifier/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
SELECT DISTINCT ?source_id ?sarrera_burua ?sarrera_testua ?wikibase_lexeme ?wikibase_lemma WHERE {
  ?wikibase_lexeme mp:P6 _:b10;
    wikibase:lemma ?wikibase_lemma.
  _:b10 mps:P6 mwb:Q1284;
    mpq:P186 ?source_id;
    mpq:P187 ?sarrera_burua;
    mpq:P198 ?sarrera_testua.
  FILTER(NOT EXISTS { ?wikibase_lexeme mp:P185 ?lila_id_st. })
}
ORDER BY (xsd:integer(?source_id))

Try it!


LiLarekin lotutako LEH sarrerak

Galdeketa honek LEH sarrerek LiLarekin dituzten loturak zerrendatzen ditu (ambiguoak barne), eta LiLa-tik sarrera bakoitzerako zenbait datu ekarri. LiLarekin galdeketa federatua egiteko adibidea. Galdeketa hau erabiltzen dugu Wikibaseko LiLa-loturak kalifikatzaileez aberasteko. 

PREFIX ontolex: <http://www.w3.org/ns/lemon/ontolex#>
PREFIX mwb: <https://monumenta.wikibase.cloud/entity/>
PREFIX mdp: <https://monumenta.wikibase.cloud/prop/direct/>
PREFIX mp: <https://monumenta.wikibase.cloud/prop/>
PREFIX mps: <https://monumenta.wikibase.cloud/prop/statement/>
PREFIX mpq: <https://monumenta.wikibase.cloud/prop/qualifier/>
PREFIX mpr: <https://monumenta.wikibase.cloud/prop/reference/>
PREFIX mno: <https://monumenta.wikibase.cloud/prop/novalue/>
PREFIX lila: <http://lila-erc.eu/ontologies/lila/>


SELECT distinct ?lila_id_st ?lila_uri ?lila_lemma (group_concat(distinct str(?lila_pos); SEPARATOR="|") as ?lila_POS) (group_concat(distinct str(?lila_gender); SEPARATOR="|") as ?lila_GENDER) ?lila_inflectionType 
                (group_concat(distinct concat(str(?sense), " (",lang(?sense),")"); SEPARATOR=", ") as ?sense_translations)
   WHERE {
?wikibase_lexeme mp:P6 [mps:P6 mwb:Q1284; mpq:P186 ?source_id; mpq:P187 ?sarrera_burua]; wikibase:lemma ?wikibase_lemma; mp:P185 ?lila_id_st. ?lila_id_st mps:P185 ?lila_id.

 bind(iri(concat("http://lila-erc.eu/data/id/",?lila_id)) as ?lila_uri)
    
     SERVICE <https://lila-erc.eu/sparql/lila_knowledge_base/sparql> { 
       select ?lila_uri ?lila_pos ?lila_lemma ?lila_gender ?lila_inflectionType ?sense
                        where 
       {?lila_uri lila:hasPOS ?lila_pos; rdfs:label ?lila_lemma 
       optional {?lila_uri lila:hasGender ?lila_gender.}
       optional {?lila_uri lila:hasInflectionType ?lila_inflectionType.}
       optional {?dict_entry ontolex:canonicalForm ?lila_uri. ?dict_entry ontolex:sense [rdfs:label ?sense]. filter(lang(?sense)="es" || lang(?sense)="pt" || lang(?sense)="en" || lang(?sense)="fr" || lang(?sense)="it")}
       } group by ?lila_uri ?lila_pos ?lila_lemma ?lila_gender ?lila_inflectionType ?sense
       }
    
  
} group by ?lila_id_st ?lila_uri ?lila_lemma ?lila_POS ?lila_GENDER ?lila_inflectionType ?sense_translations

Try it!

Adiera-objektua duten LEH sarrerak

Hainbat sarrerarentzat, euskarazko itzulpen-ordainetatik adiera-objektuak sortu ahal izan dugu. Galdeketa honek zerrendatzen ditu. 

#title: Adiera-objektua dituzten LEH sarrerak
PREFIX ontolex: <http://www.w3.org/ns/lemon/ontolex#>
PREFIX mwb: <https://monumenta.wikibase.cloud/entity/>
PREFIX mdp: <https://monumenta.wikibase.cloud/prop/direct/>
PREFIX mp: <https://monumenta.wikibase.cloud/prop/>
PREFIX mps: <https://monumenta.wikibase.cloud/prop/statement/>
PREFIX mpq: <https://monumenta.wikibase.cloud/prop/qualifier/>
PREFIX mpr: <https://monumenta.wikibase.cloud/prop/reference/>
PREFIX mno: <https://monumenta.wikibase.cloud/prop/novalue/>
PREFIX lila: <http://lila-erc.eu/ontologies/lila/>


SELECT distinct ?source_id ?sarrera_burua ?wikibase_lexeme ?wikibase_lemma ?sense ?gloss
     
   WHERE {
?wikibase_lexeme mp:P6 [mps:P6 mwb:Q1284; mpq:P186 ?source_id; mpq:P187 ?sarrera_burua]; wikibase:lemma ?wikibase_lemma.
?wikibase_lexeme ontolex:sense ?sense. ?sense skos:definition ?gloss.
   
} 
order by xsd:integer(?source_id)

Try it!

Kategoria lexikala LEH eta LiLan

#title: Different lexical category (for the same lexeme) in LEH and LiLa
PREFIX ontolex: <http://www.w3.org/ns/lemon/ontolex#>
PREFIX mwb: <https://monumenta.wikibase.cloud/entity/>
PREFIX mdp: <https://monumenta.wikibase.cloud/prop/direct/>
PREFIX mp: <https://monumenta.wikibase.cloud/prop/>
PREFIX mps: <https://monumenta.wikibase.cloud/prop/statement/>
PREFIX mpq: <https://monumenta.wikibase.cloud/prop/qualifier/>
PREFIX mpr: <https://monumenta.wikibase.cloud/prop/reference/>
PREFIX mno: <https://monumenta.wikibase.cloud/prop/novalue/>
PREFIX lila: <http://lila-erc.eu/ontologies/lila/>


SELECT distinct ?source_id ?sarrera_burua ?leh_pos ?leh_posLabel ?wikibase_lexeme ?wikibase_lemma ?wikidata ?lila_uri ?lila_pos ?lila_posLabel
     
   WHERE { 
?wikibase_lexeme mp:P6 [mps:P6 mwb:Q1284; mpq:P186 ?source_id; mpq:P187 ?sarrera_burua]; wikibase:lemma ?wikibase_lemma; wikibase:lexicalCategory ?leh_pos.
optional {?wikibase_lexeme mdp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
?wikibase_lexeme mp:P185 ?lila_id_st. ?lila_id_st mps:P185 ?lila_id; mpq:P153 ?lila_pos. bind(iri(concat("https://lila-erc.eu/lodview/data/id/",?lila_id)) as ?lila_uri)
     filter (?lila_pos != ?leh_pos) # lila_pos and leh_pos are not the same
     filter not exists { ?leh_pos mdp:P4+ ?lila_pos. } # leh_pos is not subclass of lila_pos
     filter not exists { ?lila_pos mdp:P4+ ?leh_pos. } # lila_pos is not subclass of leh_pos
     filter (?leh_pos != mwb:Q74)
   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,eu". } 
}  
order by ?leh_pos

Try it!


Wikidatarekin lotutako sarrerak

Galdeketa honek Wikidatarekin lotutakoak zerrendatzen ditu, eta Wikidatatik sarrera bakoitzerako zenbait datu ekarri. 

PREFIX ontolex: <http://www.w3.org/ns/lemon/ontolex#>
PREFIX mwb: <https://monumenta.wikibase.cloud/entity/>
PREFIX mdp: <https://monumenta.wikibase.cloud/prop/direct/>
PREFIX mp: <https://monumenta.wikibase.cloud/prop/>
PREFIX mps: <https://monumenta.wikibase.cloud/prop/statement/>
PREFIX mpq: <https://monumenta.wikibase.cloud/prop/qualifier/>
PREFIX mpr: <https://monumenta.wikibase.cloud/prop/reference/>
PREFIX mno: <https://monumenta.wikibase.cloud/prop/novalue/>
PREFIX lila: <http://lila-erc.eu/ontologies/lila/>
SELECT distinct ?source_id ?sarrera_burua ?wikibase_lexeme ?wikibase_lemma ?wikidata ?wikidata_lemma ?wikidata_POS 
     
   WHERE {
?wikibase_lexeme mp:P6 [mps:P6 mwb:Q1284; mpq:P186 ?source_id; mpq:P187 ?sarrera_burua]; wikibase:lemma ?wikibase_lemma.
?wikibase_lexeme mdp:P1 ?wd.
 bind(iri(concat(str(wd:),?wd)) as ?wikidata)
    
     SERVICE <https://query.wikidata.org/sparql> { 
       select  ?wikidata ?wikidata_lemma ?wikidata_POS 
       where {?wikidata wikibase:lemma ?wikidata_lemma; wikibase:lexicalCategory [rdfs:label ?wikidata_POS].
              filter(lang(?wikidata_POS)="en")
       } 
       } 
} 
order by xsd:integer(?source_id)

Try it!

Balizko adiera-mailako loturak Wikidatarekin

Hiztegiko euskarazko itzulpen-ordainak Wikidatan bilatzen ditu, eta lema maila bat datozen adierak zerrendatu. 

#title:LEH sarrerak eta Wikidatarekiko adiera-mailako lotura posibleak
PREFIX ontolex: <http://www.w3.org/ns/lemon/ontolex#>
PREFIX mwb: <https://monumenta.wikibase.cloud/entity/>
PREFIX mdp: <https://monumenta.wikibase.cloud/prop/direct/>
PREFIX mp: <https://monumenta.wikibase.cloud/prop/>
PREFIX mps: <https://monumenta.wikibase.cloud/prop/statement/>
PREFIX mpq: <https://monumenta.wikibase.cloud/prop/qualifier/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX dct: <http://purl.org/dc/terms/>
SELECT DISTINCT ?source_id ?wikibase_lexeme ?wikibase_lemma ?sarrera_testua ?lila_uri ?sense ?ordainak ?wikidata_lexeme ?basque_lemma ?wikidata_sense ?definition WHERE {
  ?wikibase_lexeme mp:P6 _:b141;
    wikibase:lemma ?wikibase_lemma.
  _:b141 mps:P6 mwb:Q1284;
    mpq:P186 ?source_id;
    mpq:P198 ?sarrera_testua.
  FILTER(REGEX(STR(?wikibase_lemma), "^a")) # Latin letter A only (avoids timeout)
  OPTIONAL {
    ?wikibase_lexeme mp:P185 ?lila_id_st.
    ?lila_id_st mps:P185 ?lila_id.
    BIND(IRI(CONCAT("https://lila-erc.eu/lodview/data/id/", ?lila_id)) AS ?lila_uri)
  }
  ?wikibase_lexeme ontolex:sense ?sense. ?sense skos:definition ?ordainak; mdp:P201 ?basque_lemma.
  SERVICE <https://query.wikidata.org/sparql> {
    SELECT DISTINCT ?wikidata_lexeme ?basque_lemma ?wikidata_sense ?definition WHERE {
      ?wikidata_lexeme dct:language wd:Q8752;
        wikibase:lemma ?basque_lemma;
        wikibase:lexicalCategory wd:Q24905; # verbs only (avoids timeout)
        ontolex:sense ?wikidata_sense.
      ?wikidata_sense skos:definition ?definition.
    }
  }
}
ORDER BY (xsd:integer(?source_id)) (?sense_group) (?basque_lemma) (?wikidata_sense)

Try it!

Forma flexionatuak LiLaMorph Wikibasetik

Galdeketa federatu honek LEH-ko sarrerentzat forma flexionatuak dakartza LiLaMorph Wikibasetik. 

#title: Brings up some inflected forms from LiLaMorph Wikibase (federated query)
PREFIX ontolex: <http://www.w3.org/ns/lemon/ontolex#>
PREFIX mwb: <https://monumenta.wikibase.cloud/entity/>
PREFIX mp: <https://monumenta.wikibase.cloud/prop/>
PREFIX mps: <https://monumenta.wikibase.cloud/prop/statement/>
PREFIX mpq: <https://monumenta.wikibase.cloud/prop/qualifier/>
PREFIX lmwb: <https://lilamorph.wikibase.cloud/entity/>
PREFIX lmdp: <https://lilamorph.wikibase.cloud/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?wikibase_lexeme ?wikibase_lemma ?lila_uri ?infClass ?lilamorph_lexeme (GROUP_CONCAT(DISTINCT STR(?formrep); SEPARATOR = ", ") AS ?forms) WHERE {
  ?wikibase_lexeme mp:P6 _:b117;
    wikibase:lemma ?wikibase_lemma;
    mp:P185 ?lila_id_st.
  _:b117 mps:P6 mwb:Q1284;
    mpq:P186 ?source_id;
    mpq:P187 ?sarrera_burua.
  ?lila_id_st wikibase:rank wikibase:NormalRank;
    mps:P185 ?lila_id;
    mpq:P195 _:b118.
  _:b118 rdfs:label ?infClass.
  FILTER((LANG(?infClass)) = "en")
  BIND(IRI(CONCAT("http://lila-erc.eu/data/id/", ?lila_id)) AS ?lila_uri)
  
  SERVICE <https://lilamorph.wikibase.cloud/query/sparql> {
    SELECT DISTINCT ?lilamorph_lexeme ?lila_id ?form ?formrep WHERE {
      ?lilamorph_lexeme lmdp:P14 lmwb:Q15;
        lmdp:P1 ?lila_id;
        ontolex:lexicalForm ?form.
      ?form ontolex:representation ?formrep.
    }
    LIMIT 10
  }
}
GROUP BY ?wikibase_lexeme ?wikibase_lemma ?lila_uri ?infClass ?lilamorph_lexeme ?forms
LIMIT 10

Try it!

Retrieved from "https://monumenta.wikibase.cloud/w/index.php?title=Oinarrizko_hiztegia._Latina-Euskara&oldid=204527"