Oinarrizko hiztegia. Latina-Euskara
From MLV
Gidor Bilbaoren "Oinarrizko Hiztegia. Latina-Euskara" Q1284 entitateak deskribatzen du.
Hiztegiaren edukien egituraketa
Hiztegia Wikibase honetan
Datu-base galdeketak
Sarrera guztiak
Galdeketa honek sarrera guztiak zerrendatzen ditu, LiLa eta Wikidatarekin dituzten loturekin. LiLa edo Wikidatarekiko lotura bat baino gehiago izanez gero, sarrera errepikatuta agertzen da,
PREFIX ontolex: <http://www.w3.org/ns/lemon/ontolex#>
PREFIX mwb: <https://monumenta.wikibase.cloud/entity/>
PREFIX mdp: <https://monumenta.wikibase.cloud/prop/direct/>
PREFIX mp: <https://monumenta.wikibase.cloud/prop/>
PREFIX mps: <https://monumenta.wikibase.cloud/prop/statement/>
PREFIX mpq: <https://monumenta.wikibase.cloud/prop/qualifier/>
PREFIX mpr: <https://monumenta.wikibase.cloud/prop/reference/>
PREFIX mno: <https://monumenta.wikibase.cloud/prop/novalue/>
PREFIX lila: <http://lila-erc.eu/ontologies/lila/>
SELECT distinct ?source_id ?sarrera_burua ?wikibase_lexeme ?wikibase_lemma ?wikidata ?lila_uri
WHERE {
?wikibase_lexeme mp:P6 [mps:P6 mwb:Q1284; mpq:P186 ?source_id; mpq:P187 ?sarrera_burua]; wikibase:lemma ?wikibase_lemma.
optional {?wikibase_lexeme mdp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
optional {?wikibase_lexeme mp:P185 ?lila_id_st. ?lila_id_st mps:P185 ?lila_id. bind(iri(concat("https://lila-erc.eu/lodview/data/id/",?lila_id)) as ?lila_uri)}
}
order by xsd:integer(?source_id)
LiLarekin modu unibokoan lotutako sarrerak
Galdeketa honek LiLa-rekin eta Wikidatarekin lotutakoak zerrendatzen ditu, eta LiLa-tik sarrera bakoitzerako zenbait datu ekarri.
PREFIX ontolex: <http://www.w3.org/ns/lemon/ontolex#>
PREFIX mwb: <https://monumenta.wikibase.cloud/entity/>
PREFIX mdp: <https://monumenta.wikibase.cloud/prop/direct/>
PREFIX mp: <https://monumenta.wikibase.cloud/prop/>
PREFIX mps: <https://monumenta.wikibase.cloud/prop/statement/>
PREFIX mpq: <https://monumenta.wikibase.cloud/prop/qualifier/>
PREFIX mpr: <https://monumenta.wikibase.cloud/prop/reference/>
PREFIX mno: <https://monumenta.wikibase.cloud/prop/novalue/>
PREFIX lila: <http://lila-erc.eu/ontologies/lila/>
SELECT distinct ?source_id ?sarrera_burua ?wikibase_lexeme ?wikibase_lemma ?lila_uri ?lila_lemma (group_concat(?lila_pos) as ?lila_POS) ?lila_gender ?lila_inflectionType
WHERE {
?wikibase_lexeme mp:P6 [mps:P6 mwb:Q1284; mpq:P186 ?source_id; mpq:P187 ?sarrera_burua]; wikibase:lemma ?wikibase_lemma; mp:P185 ?lila_id_st. ?lila_id_st mps:P185 ?lila_id.
?wikibase_lexeme mdp:P1 ?wikidata.
bind(iri(concat("http://lila-erc.eu/data/id/",?lila_id)) as ?lila_uri)
SERVICE <https://lila-erc.eu/sparql/lila_knowledge_base/sparql> {
select ?lila_uri ?lila_pos ?lila_lemma ?lila_gender ?lila_inflectionType ?sense
where
{?lila_uri lila:hasPOS [rdfs:label ?lila_pos]; rdfs:label ?lila_lemma
optional {?lila_uri lila:hasGender [rdfs:label ?lila_gender].}
optional {?lila_uri lila:hasInflectionType [rdfs:label ?lila_inflectionType].}
} group by ?lila_uri ?lila_pos ?lila_lemma ?lila_gender ?lila_inflectionType ?sense
}
} group by ?source_id ?sarrera_burua ?wikibase_lexeme ?wikibase_lemma ?lila_uri ?lila_lemma ?lila_POS ?lila_gender ?lila_inflectionType
order by xsd:integer(?source_id)
Wikidatarekin lotutako sarrerak
Galdeketa honek Wikidatarekin lotutakoak zerrendatzen ditu, eta Wikidatatik sarrera bakoitzerako zenbait datu ekarri.
PREFIX ontolex: <http://www.w3.org/ns/lemon/ontolex#>
PREFIX mwb: <https://monumenta.wikibase.cloud/entity/>
PREFIX mdp: <https://monumenta.wikibase.cloud/prop/direct/>
PREFIX mp: <https://monumenta.wikibase.cloud/prop/>
PREFIX mps: <https://monumenta.wikibase.cloud/prop/statement/>
PREFIX mpq: <https://monumenta.wikibase.cloud/prop/qualifier/>
PREFIX mpr: <https://monumenta.wikibase.cloud/prop/reference/>
PREFIX mno: <https://monumenta.wikibase.cloud/prop/novalue/>
PREFIX lila: <http://lila-erc.eu/ontologies/lila/>
SELECT distinct ?source_id ?sarrera_burua ?wikibase_lexeme ?wikibase_lemma ?wikidata ?wikidata_lemma ?wikidata_POS
WHERE {
?wikibase_lexeme mp:P6 [mps:P6 mwb:Q1284; mpq:P186 ?source_id; mpq:P187 ?sarrera_burua]; wikibase:lemma ?wikibase_lemma.
?wikibase_lexeme mdp:P1 ?wd.
bind(iri(concat(str(wd:),?wd)) as ?wikidata)
SERVICE <https://query.wikidata.org/sparql> {
select ?wikidata ?wikidata_lemma ?wikidata_POS
where {?wikidata wikibase:lemma ?wikidata_lemma; wikibase:lexicalCategory [rdfs:label ?wikidata_POS].
filter(lang(?wikidata_POS)="en")
}
}
}
order by xsd:integer(?source_id)